Need help with masking bloom effects

#include "ReShade.fxh"

uniform int Readme <
    ui_type = "combo";
    ui_items = "Add BLOOM_MASK_NAME=\"name\" to settings.";
> = 0;

namespace BloomMask {
    texture2D texBloomMask < source=BLOOM_MASK_NAME; > { Width = BUFFER_WIDTH; Height = BUFFER_HEIGHT; Format = RGBA8; };
    sampler2D sBloomMask { Texture = texBloomMask; };

    texture2D texBloomMask_Backup { Width = BUFFER_WIDTH; Height = BUFFER_HEIGHT; Format = RGBA8; };
    sampler2D sBloomMask_Backup { Texture = texBloomMask_Backup; };

    void PreBloomBackupPS(float4 vpos : SV_Position, float2 texcoord : TexCoord, out float3 backup : SV_Target0) {
        //Save the original backbuffer
        backup = tex2D(ReShade::BackBuffer, texcoord).rgb;
    }

    void PreBloomPS(float4 vpos : SV_Position, float2 texcoord : TexCoord, out float3 masked : SV_Target0) {
        //Set everything that should be masked to black
        masked = lerp(0.0.rrr, tex2D(ReShade::BackBuffer, texcoord).rgb, tex2Dfetch(sBloomMask, int4(vpos.xy, 0, 0)).r);
    }

    float3 PostBloomPS(float4 vpos : SV_Position, float2 texcoord : TexCoord) : SV_Target {
        //merge original and bloomed backbuffer
        return lerp(tex2Dfetch(sBloomMask_Backup, int4(vpos.xy, 0, 0)).rgb, tex2Dfetch(ReShade::BackBuffer, int4(vpos.xy, 0, 0)).rgb, tex2Dfetch(sBloomMask, int4(vpos.xy, 0, 0)).r);
    }

    float3 ShowBloomMaskPS(float4 vpos : SV_Position, float2 texcoord : TexCoord) : SV_Target {
        return tex2Dfetch(sBloomMask, int4(vpos.xy, 0, 0)).rrr;
    }
}

technique PreBloom {
    pass {
        VertexShader = PostProcessVS;
        PixelShader = BloomMask::PreBloomBackupPS;
        RenderTarget0 = BloomMask::texBloomMask_Backup;
    }
    pass {
        VertexShader = PostProcessVS;
        PixelShader = BloomMask::PreBloomPS;
    }
}

technique PostBloom {
    pass {
        VertexShader = PostProcessVS;
        PixelShader = BloomMask::PostBloomPS;
    }
}

technique ShowBloomMask {
    pass {
        VertexShader = PostProcessVS;
        PixelShader = BloomMask::ShowBloomMaskPS;
    }
}