Help needed to get a working depth check to Emboss

/*
	Full credits to the ReShade team
	Ported by Insomnia
*/

uniform float fEmbossPower <
	ui_type = "drag";
	ui_min = 0.01; ui_max = 2.0;
	ui_label = "Emboss Power";
> = 0.150;
uniform float fEmbossOffset <
	ui_type = "drag";
	ui_min = 0.1; ui_max = 5.0;
	ui_label = "Emboss Offset";
> = 1.00;
uniform float iEmbossAngle <
	ui_type = "drag";
	ui_min = 0.0; ui_max = 360.0;
	ui_label = "Emboss Angle";
> = 90.00;





//#define bEmbossDoDepthCheck 1 //-EXPERIMENTAL! If enabled, shader compares emboss samples depth to avoid artifacts at object borders.
//#define fEmbossDepthCutoff 0.0001 //-Preserves object edges from getting artifacts. If pixel depth difference of emboss samples is higher than that, pixel gets skipped.

uniform float fEmbossDepthCutoff <
	ui_label = "fEmbossDepthCutoff";
	ui_type = "drag";
	ui_min = 0.01; ui_max = 1.0;
	> = 0.2;

#include "ReShade.fxh"

float3 EmbossPass(float4 vpos : SV_Position, float2 texcoord : TEXCOORD) : SV_Target
{
	float3 res = 0;
	float3 color = tex2D(ReShade::BackBuffer, texcoord).rgb;

    float2 offset;
	sincos(radians( iEmbossAngle), offset.y, offset.x);
	float3 col1 = tex2D(ReShade::BackBuffer, texcoord - ReShade::PixelSize*fEmbossOffset*offset).rgb;
	float3 col2 = color.rgb;
	float3 col3 = tex2D(ReShade::BackBuffer, texcoord + ReShade::PixelSize*fEmbossOffset*offset).rgb;

		float depth1 = tex2D(ReShade::DepthBuffer,texcoord - ReShade::PixelSize*fEmbossOffset).rgb;
		float depth2 = tex2D(ReShade::DepthBuffer,texcoord).rgb;
		float depth3 = tex2D(ReShade::DepthBuffer,texcoord + ReShade::PixelSize*fEmbossOffset).rgb;

	
	float3 colEmboss = col1 * 2.0 - col2 - col3;

	float colDot = max(0,dot(colEmboss, 0.333))*fEmbossPower;

	float3 colFinal = col2 - colDot;

	float luminance = dot( col2, float3( 0.6, 0.2, 0.2 ) );

	color.xyz = lerp( colFinal, col2, luminance * luminance ).xyz;


        if(max(abs(depth1-depth2),abs(depth3-depth2)) > fEmbossDepthCutoff) color = res;


	return color;

}

technique Emboss_Tech
{
	pass Emboss
	{
		VertexShader = PostProcessVS;
		PixelShader = EmbossPass;
	}
}

float3 color = res = tex2D(ReShade::BackBuffer, texcoord).rgb;

NAMESPACE_ENTER(CFX)

#include CFX_SETTINGS_DEF

#if USE_EMBOSS

float4 PS_Emboss(float4 vpos : SV_Position, float2 texcoord : TEXCOORD) : SV_Target
{
	float4 res = 0;
	float4 origcolor = tex2D(RFX_backbufferColor, texcoord);

        float2 offset;
	sincos(radians( iEmbossAngle), offset.y, offset.x);
	float3 col1 = tex2D(RFX_backbufferColor, texcoord - RFX_PixelSize*fEmbossOffset*offset).rgb;
	float3 col2 = origcolor.rgb;
	float3 col3 = tex2D(RFX_backbufferColor, texcoord + RFX_PixelSize*fEmbossOffset*offset).rgb;

#if(bEmbossDoDepthCheck != 0)
	float depth1 = tex2D(RFX_depthColor,texcoord - RFX_PixelSize*fEmbossOffset).r;
	float depth2 = tex2D(RFX_depthColor,texcoord).r;
	float depth3 = tex2D(RFX_depthColor,texcoord + RFX_PixelSize*fEmbossOffset).r;
#endif
	
	float3 colEmboss = col1 * 2.0 - col2 - col3;

	float colDot = max(0,dot(colEmboss, 0.333))*fEmbossPower;

	float3 colFinal = col2 - colDot;

	float luminance = dot( col2, float3( 0.6, 0.2, 0.2 ) );

	res.xyz = lerp( colFinal, col2, luminance * luminance ).xyz;
#if(bEmbossDoDepthCheck != 0)
        if(max(abs(depth1-depth2),abs(depth3-depth2)) > fEmbossDepthCutoff) res = origcolor;
#endif
	return res;

}

technique Emboss_Tech <bool enabled = RFX_Start_Enabled; int toggle = Emboss_ToggleKey; >
{
	pass Emboss
	{
		VertexShader = RFX_VS_PostProcess;
		PixelShader = PS_Emboss;
	}
}

#endif

#include CFX_SETTINGS_UNDEF

NAMESPACE_LEAVE()

#include "ReShade.fxh"

uniform float fEmbossPower <
	ui_type = "drag";
	ui_min = 0.01; ui_max = 2.0;
	ui_label = "Emboss Power";
> = 0.150;
uniform float fEmbossOffset <
	ui_type = "drag";
	ui_min = 0.1; ui_max = 5.0;
	ui_label = "Emboss Offset";
> = 1.00;
uniform float iEmbossAngle <
	ui_type = "drag";
	ui_min = 0.0; ui_max = 360.0;
	ui_label = "Emboss Angle";
> = 90.00;

uniform bool bDepthCheck <
	ui_label = "Enable Depth Check";
> = false;

uniform float fDepthCutoff <
	ui_type = "input";
	ui_label = "Depth Cutoff";
> = 0.001;

float4 EmbossPS(float4 vpos : SV_Position, float2 texcoord : TEXCOORD) : SV_Target {
	float3 res;
	float3 origcolor = tex2D(ReShade::BackBuffer, texcoord).rgb;

	float2 offset;
	sincos(radians( iEmbossAngle), offset.y, offset.x);

	float3 col1 = tex2D(ReShade::BackBuffer, texcoord - ReShade::PixelSize*fEmbossOffset*offset).rgb;
	float3 col2 = origcolor;
	float3 col3 = tex2D(ReShade::BackBuffer, texcoord + ReShade::PixelSize*fEmbossOffset*offset).rgb;

	float3 colEmboss = col1 * 2.0 - col2 - col3;
	float colDot = max(0,dot(colEmboss, 0.333))*fEmbossPower;
	float3 colFinal = col2 - colDot;

	float luminance = dot( col2, float3( 0.6, 0.2, 0.2 ) );
	res = lerp( colFinal, col2, luminance * luminance );

	if( bDepthCheck ){
		float depth1 = ReShade::GetLinearizedDepth(texcoord - ReShade::PixelSize*fEmbossOffset).r;
		float depth2 = ReShade::GetLinearizedDepth(texcoord);
		float depth3 = ReShade::GetLinearizedDepth(texcoord + ReShade::PixelSize*fEmbossOffset).r;
		
		if( max(abs(depth1-depth2),abs(depth3-depth2)) > fDepthCutoff ){
			res = origcolor;
		}
	}

	return float4(res, 1.0);
}

technique Depth_Emboss {
	pass Emboss
	{
		VertexShader = PostProcessVS;
		PixelShader = EmbossPS;
	}
}