[SOLVED] Mipmaps and tex2D-functions

#include "ReShade.fxh"

#ifdef MIP_MAP_LEVELS
    #error "MIP_MAP_LEVELS is defined"
#else
    #define MIP_MAP_LEVELS 5
#endif

uniform int iUISource <
	ui_type = "combo";
	ui_label = "Type";
	ui_items = "BackBuffer\0Image\0";
> = 0;

uniform int iUIlod <
	ui_type = "drag";
	ui_label = "mipmap lod";
    ui_min = 0; ui_max = 4;
> = 0;

uniform int iUIType <
	ui_type = "combo";
	ui_label = "Type";
	ui_items = "tex2D()\0tex2Dlod()\0tex2Dfetch(sampler, float4)\0tex2Dfetch(sampler, int4)\0";
> = 0;

texture texImage < source = "image.jpg"; > { Width = BUFFER_WIDTH; Height = BUFFER_HEIGHT; Format = RGBA8; MipLevels = MIP_MAP_LEVELS; };
sampler2D SamplerImage { Texture = texImage; };

texture2D texMipMap { Width = BUFFER_WIDTH; Height = BUFFER_HEIGHT; Format = RGBA8; MipLevels = MIP_MAP_LEVELS; };
sampler2D SamplerMipMap { Texture = texMipMap; };
sampler2D SamplerMipMapLODBias { Texture = texMipMap; MipLODBias = MIP_MAP_LEVELS; };

float3 PreRender_PS(float4 vpos : SV_Position, float2 texcoord : TexCoord) : SV_Target {
    float3 color;

    if(iUISource == 1)
        color = tex2D(SamplerImage, texcoord).rgb;
    else
        color = tex2D(ReShade::BackBuffer, texcoord).rgb;

    return color;
}

float3 Final_PS(float4 vpos : SV_Position, float2 texcoord : TexCoord) : SV_Target {
    float3 color;

    if(iUIType == 0)
        color = tex2D(SamplerMipMapLODBias, texcoord).rgb;
    else if(iUIType == 1)
        color = tex2Dlod(SamplerMipMap, float4(texcoord.xy, 0, iUIlod)).rgb;
    else if(iUIType == 2)
        //d3d9: gives same result as tex2Dlod (mipmap interpolated over the whole screen; weird, because tex2Dfetch supposedly takes an int4 as parameter #2)
        //d3d11: Pixel at position (0/0) gets strechted over the whole screen (thats expected)
        //OGL: error: implicit cast from "ivec4" to "ivec2"; incompatible type for parameter #2
        color = tex2Dfetch(SamplerMipMap, float4(texcoord.xy, 0, iUIlod)).rgb;
    else
        //d3d9: Pixel at position (0/0) gets strechted over the whole screen (at least, that's how it looks like)
        //d3d11: with increasing lod-value the image shrinks towards the upper left corner of the screen
        //OGL: error: implicit cast from "ivec4" to "ivec2"; incompatible type for parameter #2
        color = tex2Dfetch(SamplerMipMap, int4(vpos.xy, 0, iUIlod)).rgb;

    return color;
}

technique MipMap
{
	pass {
		VertexShader = PostProcessVS;
		PixelShader = PreRender_PS;
                RenderTarget = texMipMap;
	}
    pass {
		VertexShader = PostProcessVS;
		PixelShader = Final_PS;
	}
}