Kuwahara Shader as DoF

/*
A slightly altered version of the basic Kuwahara filter

source:
Anisotropic Kuwahara Filtering on the GPU
www.kyprianidis.com
Paper on the related shader : http://www.kyprianidis.com/p/pg2009/jkyprian-pg2009.pdf
Preview App' : https://code.google.com/archive/p/gpuakf/downloads
Code : https://code.google.com/archive/p/gpuakf/source/default/source
Use this code in accordance to the license holder's license !

Ported over to Reshade by Eideren
DoF Effects by Moriz
*/


uniform int Iterations <
	ui_type = "drag";
	ui_min = 0.0;
	ui_max = 16.0;
	ui_label = "Iterations";
	ui_tooltip = "VERY HEAVY performance cost. Best to leave this at 4, unless SampleDistance is also high.";
> = 4;

uniform float SampleDistance <
	ui_type = "drag";
	ui_min = 0.0;
	ui_max = 10.0;
	ui_label = "SampleDistance";
	ui_tooltip = "Bigger this is, the stronger the effect.\nWarning: reduces accuracy if set too high, without also adjusting Iterations.";
> = 6.4;

uniform float DepthNearLimit <
	ui_type = "drag";
	ui_min = 0.0;
	ui_max = 0.1;
	ui_label = "Depth Near Limit";
	ui_tooltip = "Blurs object close to the screen.";
> = 0.01;

uniform float DepthFarLimit <
	ui_type = "drag";
	ui_min = 0.0;
	ui_max = 1.0;
	ui_label = "Depth Far Limit";
	ui_tooltip = "Blurs object in the distance.";
> = 0.27;

uniform float FocusDOFWidth <
	ui_type = "drag";
	ui_min = 0.0;
	ui_max = 0.4;
	ui_label = "Focus DOF Width";
	ui_tooltip = "Adjusts how far further DoF extends past focussed object.\nIf set to 0.0, Autofocus will only adjust to the focussed object.";
> = 0.06;

uniform float FocusSpeed <
	ui_type = "drag";
	ui_min = 0.0;
	ui_max = 1.0;
	ui_label = "Focus Speed";
> = 0.2;

uniform float RightClickFocusOffsetX <
	ui_type = "drag";
	ui_min = 0.0;
	ui_max = 1.0;
	ui_label = "Right Click Focus Offset X Axis";
	ui_tooltip = "Also affects Screen Center focus.\n0.0 is top of the screen.";
> = 0.5;

uniform float RightClickFocusOffsetY <
	ui_type = "drag";
	ui_min = 0.0;
	ui_max = 1.0;
	ui_label = "Right Click Focus Offset Y Axis";
	ui_tooltip = "Also affects Screen Center focus.\n0.0 is left side of the screen.";
> = 0.5;

uniform bool AlwaysUseScreenCenter <
    ui_type = "toggle";
    ui_label = "ALways Use Screen Center";
	ui_tooltip = "Disables mouse focussing. Always focuses onto a predetermined point on the screen.";
> = false;

uniform bool ShowDebug <
    ui_type = "toggle";
    ui_label = "Show Debug";
> = false;

uniform bool IgnoreDepthOne <
    ui_type = "toggle";
    ui_label = "Ignore Depth = 1";
	ui_tooltip = "Ignores the skybox.\nAlso affects character select screen and world map screen.";
> = true;

uniform bool UseAutoFocus <
    ui_type = "toggle";
    ui_label = "Use Auto Focus";
	ui_tooltip = "Turn off to disable all autofocus.";
> = true;

uniform bool AllowNearLimitAdjustments <
	ui_type = "toggle";
    ui_label = "Allow Near Limit Adjustments";
	ui_tooltip = "Turn on to allow near DoF boundary to move forward with autofocus.\nNot recommended for 3rd person perspectives.";
> = false;

uniform float NearLimitAdjustmentsMulti <
	ui_type = "drag";
	ui_min = 0.0001;
	ui_max = 1.0;
	ui_label = "Near Limit Adjustments Multiplier";
	ui_tooltip = "Controls the magnitude of Near Limit Adjustments";
> = 0.01;


uniform float2 MouseCoord < source = "mousepoint"; >;
uniform float frametime < source = "frametime"; >;
uniform bool RightClick < source = "mousebutton"; keycode = 1; toggle = false; >;

#include "ReShade.fxh"
#include "DrawText.fxh"

#define TexChannel0 (ReShade::BackBuffer)
#define TexChannel0_size (ReShade::ScreenSize.xy)

// Force lod for lower Shader Models
#define SAMPLE(s,uv) tex2Dlod(s, float4(uv, 0, 0))

texture FocusPointTex { Width = 1; Height = 1; Format = R16F; };
sampler FocusPointSampler { Texture = FocusPointTex; };

texture FocusPointTexPrev { Width = 1; Height = 1; Format = R16F; };
sampler FocusPointPrevSampler { Texture = FocusPointTexPrev; };

float4 KuwaharaModEffect(float effectPower, float2 tex) {
    float2 uv = tex.xy;
	float n = float((Iterations + 1) * (Iterations + 1));
    float3 m[4];
	float3 s[4];
	for (int k = 0; k < 4; ++k) {
		m[k] = (0.0);
		s[k] = (0.0);
	}

    for (int j = -Iterations; j <= 0; ++j)  {
		for (int i = -Iterations; i <= 0; ++i)  {
			float3 c = SAMPLE(TexChannel0, uv + float2(i,j) / TexChannel0_size * effectPower).rgb;
			m[0] += c;
			s[0] += c * c;
		}
	}
	
	for (int j = -Iterations; j <= 0; ++j)  {
		for (int i = 0; i <= Iterations; ++i)  {
			float3 c = SAMPLE(TexChannel0, uv + float2(i,j) / TexChannel0_size * effectPower).rgb;
			m[1] += c;
			s[1] += c * c;
		}
	}
	
	for (int j = 0; j <= Iterations; ++j)  {
		for (int i = 0; i <= Iterations; ++i)  {
			float3 c = SAMPLE(TexChannel0, uv + float2(i,j) / TexChannel0_size * effectPower).rgb;
			m[2] += c;
			s[2] += c * c;
		}
	}
	
	for (int j = 0; j <= Iterations; ++j)  {
		for (int i = -Iterations; i <= 0; ++i)  {
			float3 c = SAMPLE(TexChannel0, uv + float2(i,j) / TexChannel0_size * effectPower).rgb;
			m[3] += c;
			s[3] += c * c;
		}
	}
	
	float4 fragColor = 0;
	float min_sigma2 = 1e+2;
	float3 median = 0;
	for (int k = 0; k < 4; ++k) {
		m[k] /= n;
		s[k] = abs(s[k] / n - m[k] * m[k]);
		
		float sigma2 = s[k].r + s[k].g + s[k].b;
		median += m[k] / 4;
		if (sigma2 < min_sigma2) {
			min_sigma2 = sigma2;
			fragColor = float4(m[k], 1.0);
		}
	}
    
	return fragColor;
}

float GetFocusPass(float4 vpos : SV_POSITION, float2 texcoord : TexCoord) : SV_Target {
	float focusPoint = (AlwaysUseScreenCenter || RightClick) ? ReShade::GetLinearizedDepth(float2(0.5, 0.5)) : ReShade::GetLinearizedDepth(MouseCoord * ReShade::PixelSize);

	float focusPointPrev = tex2D(FocusPointPrevSampler, float2(RightClickFocusOffsetX, RightClickFocusOffsetY)).x;

	float focusSpeedMulti = (RightClick) ? 2.0 : 1.0;
	focusPoint = (focusPoint >= 1.0 && IgnoreDepthOne) ? focusPointPrev : focusPoint;

	return lerp(focusPointPrev, focusPoint, FocusSpeed*focusSpeedMulti*10.0/frametime);
}

float4 DofPass(float4 vpos : SV_Position, float2 tex : TexCoord) : SV_Target
{
	float depth = ReShade::GetLinearizedDepth(tex);

	float focusPoint = tex2D(FocusPointSampler, float2(0.5, 0.5)).x;
	
    if (ShowDebug) {
        float res = -0.1;

		int line0[13] = { __M, __o, __u, __s, __e, __Space, __C, __o, __o, __r, __d, __Colon, __Space };

		DrawText_String(float2(100.0, 132.0), 32, 1, tex, line0, 13, res);
		DrawText_Digit(DrawText_Shift(float2(200.0, 132.0), int2(13, 0), 32, 1), 32, 1, tex, 0, MouseCoord.x, res);
        DrawText_Digit(DrawText_Shift(float2(400.0, 132.0), int2(13, 0), 32, 1), 32, 1, tex, 0, MouseCoord.y, res);
        DrawText_Digit(DrawText_Shift(float2(500.0, 132.0), int2(13, 0), 32, 1), 32, 1, tex, 3, focusPoint, res);

		if ( res != -0.1)
			return res;
    }

    if (depth >= 1.0 && IgnoreDepthOne) {
        return tex2D(ReShade::BackBuffer, tex).rgba;
    }

	if (depth >= DepthNearLimit && depth <= DepthFarLimit && !AllowNearLimitAdjustments) {
		return tex2D(ReShade::BackBuffer, tex).rgba;
	}

    float focusNear = (focusPoint < DepthNearLimit && UseAutoFocus) ? focusPoint : DepthNearLimit;
    float focusFar = (focusPoint > DepthFarLimit && UseAutoFocus) ? saturate(focusPoint + FocusDOFWidth) : DepthFarLimit;

	if (AllowNearLimitAdjustments && UseAutoFocus) {
		focusNear = saturate(NearLimitAdjustmentsMulti * (focusPoint - FocusDOFWidth));
	}

    float calcDepthGradient = (depth < focusNear && depth < focusFar) ? sqrt(saturate(1 - (depth / focusNear))) : sqrt(saturate((depth - focusFar) / (1 - focusFar)));

	float scaledSampleDistance = SampleDistance / (Iterations+1) * calcDepthGradient;

    return KuwaharaModEffect(scaledSampleDistance, tex);
}

float StorePrevFocusPass(float4 vpos : SV_POSITION, float2 texcoord : TexCoord) : SV_Target {
	return tex2D(FocusPointSampler, float2(0.5, 0.5)).x;
}

technique KuwaharaModDOF
{
	pass
	{
		VertexShader = PostProcessVS;
		PixelShader = GetFocusPass;
		RenderTarget = FocusPointTex;
	}
	pass
	{
		VertexShader = PostProcessVS;
		PixelShader = DofPass;
	}
	pass
	{
		VertexShader = PostProcessVS;
		PixelShader = StorePrevFocusPass;
		RenderTarget = FocusPointTexPrev;
	}
}